EasyLanguage Snippets

Pyramaniac

2 Comments

Code to pyramid up to N contracts on a day trade basis.

input: maxSize(5),startTime(1000),endTime(1555);
var: stb(0),sts(0),tpAmt(0),lprft(0),sprft(0);


stb = High + minMove/priceScale;
sts = Low - minMove/priceScale;

print(date," ",time," ",stb," ",sts," ",currentShares);

	
if (time > startTime and time < endTime ) then
begin
	tpAmt = average(range,10);
    if(high>high[1]) then lprft = highD(0)+1*tpAmt;
	if(low < low[1]) then sprft = lowD(0) -1*tpAmt;
	if(currentShares < maxSize and c < average(c,9) and low < low[1] and close < close[1]) then buy("pyrabuy")next bar at sts limit;
	if(currentShares < maxSize and c < average(c,9) and high >high[1] and close > close[1]) then sellShort("pyrasell") next bar at stb limit;

end;

//if(currentShares >= maxSize and marketPosition = 1) then sell("longmaxliq") next bar sts stop;
//if(currentShares >= maxSize and marketPosition =-1) then buyToCover("shortmaxliq") next bar stb stop;
if(marketPosition = 1) then sell("longProf") next bar lprft limit;
if(marketPosition =-1) then buytoCover("shortProf") next bar at sprft limit;
setexitonclose;
Uncategorized

Final Version of Geo’s Turtle with Virtual Trading

Leave a comment

Final version posted below. A little advanced but if you can follow and make sense of it then you are well along on becoming an EasyLanguage programmer.

inputs: absEntryChanLen(55),entryChanlen(20),exitChanLen(10),
	lastTradeLoserFilter(false),accountSize(100000),riskPerTradePer(.01);

vars:lastTradeLoser(true),mp(0),virtmp(0),tradeProfit(0),
	virtBuyPrice(0),virtSellPrice(0),
	virtLongLiqPrice(0),virtShortLiqPrice(0),
	virtLongLoss(0),virtShortLoss(0),
	myFillPrice(0),N(0),N$(0),dollarRisk(0),lotSize(0),
	stopLoss(0),buyPrice(0),sellPrice(0),
	hh20(0),hh55(0),ll20(0),ll55(0),iCnt(0),initPrice(0),stopLossPts(0),debug(false);

mp = marketPosition;

if mp = 0 then
begin
	N = AvgTrueRange(20); 
	N$ = N*BigPointValue;  
	dollarRisk = AccountSize * riskPerTradePer; 
	lotSize = IntPortion(DollarRisk/N$); 
	if lotSize < 1 then lotSize = 1;
	StopLoss = 2 * N$ * lotSize;
	StopLossPts = 2 * N * lotSize;
	hh20 = highest(high,entryChanLen);
	hh55 = highest(high,absEntryChanLen);
	ll20 = lowest(low,entryChanLen);
	ll55 = lowest(low,absEntryChanLen);
end;
 
If mp <> 1 and mp[1] = 1 then
Begin
	tradeProfit = ExitPrice(1) - EntryPrice(1);
	lastTradeLoser = true;
	If tradeProfit > 0 then lastTradeLoser = false;	
	if debug then 
		print(date," Long Trader ",tradeProfit*bigPointValue," ",lastTradeLoser,
		" ExitPrice ",ExitPrice(1):6:6," entryPrice ",entryPrice(1):6:6);
end;
If mp <> -1 and mp[1] = -1 then
Begin
	tradeProfit = EntryPrice(1) - ExitPrice(1);
	lastTradeLoser = true;
	If tradeProfit > 0 then lastTradeLoser = false;
	if debug then
		print(date," **** Short Trader ",tradeProfit*bigPointValue," ",lastTradeLoser,
		" mp ",mp," ",mp[1]);	
end;

If lastTradeLoserFilter = False then lastTradeLoser = True;

If lastTradeLoser = False then
Begin
	if debug then
		print(date," In Virtual Section And VirtTmp = ",virTmp); 
	If(virtmp = 1) then
	Begin
	    virtLongLiqPrice = maxList(lowest(low[1],exitChanLen),virtLongLoss);
		if(virtualLongExit(virtLongLiqPrice,1,myFillPrice) =1) then
		Begin
			tradeProfit = myFillPrice - virtBuyPrice;  
			If tradeProfit < 0 then lastTradeLoser = true; 
			virtmp = 0;
			if debug then print(" Long Exit @ ",myFillPrice);
		end;	
	end;		
	If(virtmp = -1) then
	Begin
		virtShortLiqPrice = minList(highest(high[1],exitChanLen),virtShortLoss);
		if(virtualShortExit(highest(high[1],exitChanLen),1,myFillPrice) =1) then
		Begin
			tradeProfit = virtSellPrice - myFillPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			virtmp = 0;
			if debug then print(" ShortExit @ ",myFillPrice);
		end;
	end;		
	if(virtualBuy(highest(high[1],entryChanLen),1,myFillPrice) = 1) then
	Begin
		if virtmp <> 1 then
		begin
			virtBuyPrice = myFillPrice;
			virtLongLoss = myFillPrice - 2*N;
			virtmp = 1;
			tradeProfit = 0;
			If virtmp[1] = -1 then tradeProfit = virtSellPrice - virtBuyPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			if debug then print(" Long @ ",myFillPrice);
		end;
	end;
	if(virtualSell(lowest(low[1],entryChanLen),1,myFillPrice) = 1) then
	Begin
		if virtmp <> -1 then
		begin
			virtsellPrice = myFillPrice;
			virtShortLoss = myFillPrice + 2*N;
			virtmp = -1;
			tradeProfit = 0;
			If virtmp[1] = 1 then tradeProfit =  virtBuyPrice - virtSellPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			if debug then print(" Short @ ",myFillPrice);
		end;
	end;
	if debug then print("End of Virtual Module : virTmp = ",virTmp);
end;
 			
for iCnt = 0 to 3
begin
	if lastTradeLoser then
	begin
		if mp <> -1 and currentContracts = iCnt * lotSize then
		begin
			buyPrice = hh20 + iCnt * N/2;
		end;
		if mp <> 1 and currentContracts = iCnt * lotSize then
		begin	
			sellPrice = ll20 - iCnt * N/2;
		end;
		virTmp = 0;		
	end;
	
	if lastTradeLoser = false then
	begin
		if mp <> -1 and currentContracts = iCnt * lotSize then
		begin
			buyPrice = hh55 + iCnt * N/2;
		end;
		if mp <> 1 and currentContracts = iCnt * lotSize then
		begin	
			sellPrice = ll55 - iCnt * N/2; 
		end;
//		virTmp = 0;
	end;				
end;

if lastTradeLoser then 
begin
	if currentContracts < 4 * lotsize then Buy ("Turtle20Buy") lotSize contracts next bar at buyPrice stop;
	if currentContracts < 4 * lotsize then Sellshort ("Turtle20Sell") lotsize contracts next bar at sellPrice stop;
	if currentContracts < 4 * lotsize and debug then print(date," 20sellPrice ",sellPrice:6:6," ",currentContracts);
end;

if lastTradeLoser = false then
begin
	if currentContracts < 4 * lotsize then Buy ("Turtle55Buy") lotSize contracts next bar at buyPrice stop;
	if currentContracts < 4 * lotsize then Sellshort ("Turtle55Sell") lotsize contracts next bar at sellPrice stop;
	if debug then print(date," ",iCnt," 55sellPrice ",sellPrice:6:6);
end;

If mp = 1 then Sell ("TurtleLExit") next bar at lowest(low,exitChanLen) stop;
If mp = -1 then BuyToCover("TurtleSExit") next bar at highest(high,exitChanLen) stop;

If mp = 1 then Sell ("TurtleLExit2N") next bar at entryPrice - stopLossPts stop;
If mp = -1 then BuyToCover("TurtleSExit2N") next bar at entryPrice + stopLossPts stop;
Uncategorized

One System From The Book

Leave a comment

Just wanted to bring one of the systems that I developed for the book to everybody’s attention. This is a simple system that puts on two contracts and peels one off after a certain profit and then lets the other one ride. Its a mini-Russell system. Full code is disclosed in the book – source code can be imported into other applications.  The object of this code is to demonstrate multiple contracts and money management techniques.  Remember –

THERE IS A SUBSTANTIAL RISK OF LOSS IN TRADING. IT IS IN THE NATURE OF COMMODITY TRADING THAT WHERE THERE IS THE OPPORTUNITY FOR PROFIT, THERE IS ALSO THE RISK OF LOSS. COMMODITY TRADING INVOLVES A CERTAIN DEGREE OF RISK, AND MAY NOT BE SUITABLE FOR ALL INVESTORS. PAST PERFORMANCE IS NOT NECESSARILY INDICATIVE OF FUTURE RESULTS.
THE HIGH DEGREE OF LEVERAGE THAT IS FOUND IN FUTURES (BECAUSE OF SMALL MARGIN REQUIREMENTS) CAN WORK AGAINST YOU AS WELL AS FOR YOU. I.E. YOU CAN HAVE LARGE LOSSES AS WELL AS LARGE GAINS.

GeoRussell

Uncategorized

This Code Uses A Loop To Calculate Buy/Sell Levels Based on Current Position

Leave a comment

Instead of doing this:

if currentshares = LTT then begin 
 buy("B-20A.5") LTT shares next bar highest(h,20)[BB] + (0.5*N) or higher; 
 buy("B-20A 1") LTT shares next bar highest(h,20)[BB] + (1.0*N) or higher; 
 buy("B-20A1.5") LTT shares next bar highest(h,20)[BB]+ (1.5*N) or higher; 
 end; 
 if currentshares = LTT * 2 then begin 
 buy("B-20B 1") LTT shares next bar highest(h,20)[BB] + (1.0*N) or higher; 
 buy("B-20B1.5") LTT shares next bar highest(h,20)[BB] + (1.5*N) or higher; 
 end; 
 if currentshares = LTT * 3 then 
 buy("B-20C1.5") LTT shares next bar highest(h,20)[BB] + (1.5*N) or higher; 
end;

Just do this:

for iCnt = 0 to 3
begin
	if lastTradeLoser then
	begin
		if mp <> -1 and currentContracts = iCnt * lotSize then
		begin
			buyPrice = hh20 + iCnt * N/2;
		end;		
	end;
end;
if lastTradeLoser then
begin
	if currentContracts < 4 * lotsize then Buy ("Turtle20Buy") lotSize contracts next bar at buyPrice stop;
end;

Instead of having multiple buy orders at different levels -simply change your buy levels using the for-next loop and issue just one order. Only problem is you can only issue one buy order per bar. Whereas the former approach will place multiple orders for the next bar. Usually this will not cause a problem unless your buy/sell levels are very close. The use of the for-next loop is up to one's own programming style. I like the for-next loop.

Uncategorized

A For-Loop to Calculate Different Buy/Sell Levels – Turtle Style

Leave a comment

Can you figure out what this is doing?

 

for iCnt = 0 to 3
begin
     if lastTradeLoser then
     begin
          if mp <> -1 and currentContracts = iCnt * lotSize then
          begin
	     buyPrice = hh20 + iCnt * N/2;
          end;
          if mp <> 1 and currentContracts = iCnt * lotSize then
          begin	
	    sellPrice = ll20 - iCnt * N/2;
          end;
          virTmp = 0;		
     end;

     if lastTradeLoser = false then
     begin
	   if mp <> -1 and currentContracts = iCnt * lotSize then
	   begin
	       buyPrice = hh55 + iCnt * N/2;
	   end;
	   if mp <> 1 and currentContracts = iCnt * lotSize then
	   begin	
		sellPrice = ll55 - iCnt * N/2;
	   end;
	   virTmp = 0;
     end;				
end;
Uncategorized

Using Virtual Trading Functions to Create Last Trade Loser Filter

Leave a comment

The following code uses our new functions to synthetically keep track of our trading to determine when to enter a new trade. The Turtle System only took trades after a losing trade took place. Even with the Virtual Trade functions you still need to keep track of whether the entries/exits generated a profitable trade. It simple enough to track the real trades – compare the entries/exits when a the market position changes. 

inputs: absEntryChanLen(55),entryChanlen(20),exitChanLen(10),lastTradeLoserFilter(false);

vars:lastTradeLoser(true),mp(0),virtmp(0),tradeProfit(0),virtBuyPrice(0),virtSellPrice(0),
myFillPrice(0);
mp = marketPosition;

If mp <> 1 and mp[1] = 1 then
Begin
	tradeProfit = ExitPrice(1) - EntryPrice(1);
	If tradeProfit > 0 then lastTradeLoser = false;
	print(date," Long Trader ",tradeProfit);
end;
If mp <> -1 and mp[1] = -1 then
Begin
	tradeProfit = EntryPrice(1) - ExitPrice(1);
	If tradeProfit > 0 then lastTradeLoser = false;
	print(date," Short Trader ",tradeProfit," ",lastTradeLoser);	
end;

If lastTradeLoserFilter = False then lastTradeLoser = True;

If lastTradeLoser = False then
Begin
	print(date," In Virtual Section And VirtTmp = ",virTmp);
	If(virtmp = 1) then
	Begin
		if(virtualLongExit(lowest(low[1],exitChanLen),1,myFillPrice) =1) then
		Begin
			tradeProfit = myFillPrice - virtBuyPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			virtmp = 0;
		end;
	end;	
	If(virtmp = -1) then
	Begin
		if(virtualShortExit(highest(high[1],exitChanLen),1,myFillPrice) =1) then
		Begin
			tradeProfit = virtSellPrice - myFillPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			virtmp = 0;
		end;
	end;		
	if(virtualBuy(highest(high[1],entryChanLen),1,myFillPrice) = 1) then
	Begin
		if virtmp <> 1 then
		begin
			virtBuyPrice = myFillPrice;
			virtmp = 1;
			tradeProfit = 0;
			If virtmp[1] = -1 then tradeProfit = virtSellPrice - virtBuyPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
		end;
	end;
	if(virtualSell(lowest(low[1],entryChanLen),1,myFillPrice) = 1) then
	Begin
		if virtmp <> -1 then
		begin
			virtsellPrice = myFillPrice;
			virtmp = -1;
			tradeProfit = 0;
			If virtmp[1] = 1 then tradeProfit =  virtBuyPrice - virtSellPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
		end;
	end;
	print("End of Virtual Module : virTmp = ",virTmp);
end;
Uncategorized

Replicate Turtle Trading by Creating Virtual Trade Functionality

Aside Leave a comment

My next little project is to create an EasyLanguage extender by creating a virtual trading function. The Turtle System always waits until a losing trade prior to taking a new trade. In EasyLanguage this doesn’t exist. This is similar to my Ghost Trader in Building Winning Trading Systems with TradeStation (1st and 2nd edition.)

In order to virtualize theoretical positions you must have the ability to enter/exit long/short positions. To carry this out we will create four functions:

virtualBuy
virtualSell
virtualLongExit
virtualShortExit

Information will need to be passed back and forth between the call program and the functions. Here is the template of the virtualBuy:

 Inputs: price(numericSimple),orderType(numericSimple),fillPrice(numericRef);
{Function to see if a virtual buy order was filled - we are passing the entry price, orderType
[stop,limit,market] and we will reply with with true or false and the fill price.
orderType: 
1 - Stop
2 - Limit
3 - Market}

VirtualBuy = 0;
Switch(orderType) 
Begin
Case 1:
	If high >= price then
	Begin
		fillPrice = maxList(open,price); {check for gap open}
		VirtualBuy = 1;
	end;
Case 2:
	If low < price then
	Begin
		fillPrice = minList(open,price); {check for gap open}
		VirtualBuy = 1;
	end;
Case 3:
	Begin
		fillPrice = open;
		VirtualBuy = 1;
	end;
Default:
	fillPrice = 999999;
	VirtualBuy = 0;
End;

Backtesting with [Trade Station,Python,AmiBroker, Excel]. Intended for informational and educational purposes only!