Category Archives: Uncategorized

Further Clarification on Data Aliasing

I was speaking with Mike Chalek on the phone this weekend concerning Data Aliasing and he felt this post was a little confusing. After re-reading it I can see where he is coming from. Using the same example let me see if I can clarify: assume the trading day is Wednesday and you want to keep track of the slope of a 19-day weighted moving average of data2 (weekly bars) by using a variable. The following code will give an erroneous result:

wAvg = wAverage(c of data2,19);
mySlope = wAvg – wAvg[1];

If you interrogate mySlope intra-week then it will always be equal to zero. The wAvg is by default tied to data1 which in this case is daily bars. So the value of wAvg is carried over from one day to the next. It only changes when the average of the weekly bar changes and that only occurs on Friday.

There are two possible solutions:

Without the use of data aliasing – inLine function calls
mySlope = wAverage(c of data2,19) – wAverage(c[1] of data2,19) ;

With the use of data aliasing –
vars: wAvg(close of data2,0);

wAvg = wAverage(c of data2,19);
mySlop = wAvg – wAvg[1];

Either examples will work, but if you have several variables tied to a different data stream, then the code will be much cleaner looking using data aliasing – plus it cuts down on multiple function calls.

Using Multiple Time Frames in a Strategy

I have been working on a project where the strategy combined daily and weekly bars.  Keeping track of the two time frames was, at one time, not that easy.  However, with TradeStation’s Data Aliasing it is no problem at all.  We all know that Data 1 is the highest resolution time frame and is the one used for trade execution.   Data 2 can be a different market or a different time from of the same market.  TradeStation allows for multiple data streams.  Take a look at the following output in table 1.  Wavg is a nine period moving average of weekly crude data.  Wavg[1] is the prior value of the moving average.  If you wanted to make a trading decision on a daily bar basis by looking at the slope of the Wavg you couldn’t.  The Wavg and Wavg[1] only changes at the beginning of the next week.  Most traders want to be able to make a trading decision intra-week by examining the current values of the Davg1, Davg2 and the slope of Wavg.  During the week the slope of Wavg is ZERO.

table 1
Date    Davg1 Davg2 Wavg Wavg[1]
1151019 46.94 46.38 46.17 46.17
1151020 47.01 46.54 46.17 46.17
1151021 47.00 46.69 46.17 46.17
1151022 46.95 46.74 46.17 46.17
1151023 46.93 46.70 46.54 46.17<< changed here
1151026 46.83 46.55 46.54 46.54
1151027 46.71 46.47 46.54 46.54
1151028 46.74 46.44 46.54 46.54
1151029 46.74 46.40 46.54 46.54
1151030 46.73 46.39 46.60 46.54
1151102 46.57 46.37 46.60 46.60
1151103 46.55 46.45 46.60 46.60
1151104 46.36 46.44 46.60 46.60

Now look at table 2.   The Wavg is not being updated on a daily  basis but on a weekly basis.  The current Wavg doesn’t become the prior Wavg on each daily bar.  Wavg[1] stays the same until a new weekly bar occurs.  You can now make a trading decision intra-week by examining the slope of the Wavg.  Each time frame update should only occur when a new bar of that same time frame is generated.  This feature is really cool and is easy to implement.  

table2
Date      Davg1 Davg2 Wavg Wavg[1]
1151019 46.94 46.38 46.17 45.75 < notice how the Wavg and Wavg[1] are always different
1151020 47.01 46.54 46.17 45.75
1151021 47.00 46.69 46.17 45.75
1151022 46.95 46.74 46.17 45.75
1151023 46.93 46.70 46.54 46.17
1151026 46.83 46.55 46.54 46.17
1151027 46.71 46.47 46.54 46.17
1151028 46.74 46.44 46.54 46.17
1151029 46.74 46.40 46.54 46.17
1151030 46.73 46.39 46.60 46.54
1151102 46.57 46.37 46.60 46.54
1151103 46.55 46.45 46.60 46.54
1151104 46.36 46.44 46.60 46.54

 

Here is the code that utilizes Data Aliasing. All I did was declare the weekly avg variable and tied it to data2.

vars: mavShortDaily(0),mavLongDaily(0);
vars: mavWeekly(0,data2);

mavShortDaily = average(c,19);
mavLongDaily = average(c,39);

mavWeekly = average(C of data2, 9);

If mavShortDaily > mavLongDaily and mavWeekly > mavWeekly[1] then buy this bar on close;
If mavShortDaily < mavLongDaily and mavWeekly < mavWeekly[1] then sellshort this bar on close;

print(date," ",mavShortDaily," ",mavLongDaily," ",mavWeekly," ",mavWeekly[1]);

Notice how the variable mavWeekly was tied to data2. When you delcare a variable that is tied to another data other than data1 you can put the data stream right in the variable delcaration : mavWeekly(0,data2).

How to Round Up/Down To Nearest Tick in EasyLanguage

This is how you round to the nearest tick in EasyLanguage – helpful when plotting
price based indicators. Also the formula for calculating the min tick value is given.



vars: minTick(0),testPrice(0);

minTick = minMove/priceScale;
testPrice = close * .21 * range;

// round up
value1 = testPrice + (minTick-mod(testPrice,minTick));
// round dn
value2 = testPrice - (mod(testPrice,minTick));

{mod is a call to the modulus function
 aka remainder function -- mod(12,5) = 2 -- 12/5 = 2 Remainder 2
 say ES testPrice = 1123.57
     minTick = .25
     1123.57 + (0.25 - mod(1123.57,0.25)) = 1123.57 + 0.25 - 0.07 = 1123.75}

Correction to Thermostat and Bandit Description in Book

A very astute reader of the BWTSwTS2 has brought to my attention  errors in my description of the Thermostat and Bollinger Bandit algorithms. In the Thermo description I incorrectly used the words yesterday and today. The code is correct in the book. Thanks to John for finding this!

Corrected description follows:

….If today’s closing price is greater than the average of today’s high,low and close, then we feel tomorrow’s action will probably be bearish. However, if today’s closing price is less than or equal to the average of today’s high, low, and close, then tomorrow’s market will behave in a bullish manner.

In addition John uncovered a typo as well for the Bollinger Bandit description – when I stated BELOW I meant ABOVE and vice versa.

Corrected description follows:

If liqPoint is BELOW the upband, we will liquidate a long position if today’s market action  <= liqPoint.

 If liqPoint is ABOVE the dnband, we will liquidate a long position if today’s market action  >= liqPoint.

 

Correct King Keltner Easy Language

Several have brought it to my attention that the King Keltner code in the book is missing a couple of lines. Here’s the complete code in its entirety. Thanks for bringing this to my attention.



[LegacyColorValue = true]; 

{King Keltner Program
King Keltner by George Pruitt -- based on trading system presented by Chester Keltner
 -- an example of a simple, robust and effective strategy}

Inputs: avgLength(40),atrLength(40);
Vars: upBand(0),dnBand(0),liquidPoint(0),movAvgVal(0);

movAvgVal = average((h+l+c)/3,avgLength);

upBand = movAvgVal + AvgTrueRange(atrLength);
dnBand = movAvgVal - AvgTrueRange(atrLength);

{Remember buy stops are above the market and sell stops are below the market
 -- if the market gaps above the buy stop, then the order turns into a market order
 vice versa for the sell stop}

if(movAvgVal > movAvgVal[1]) then Buy ("KKBuy") tomorrow at upBand stop;
if(movAvgVal < movAvgVal[1]) then SellShort("KKSell")tomorrow at dnBand stop;

liquidPoint = movAvgVal;
 
if(MarketPosition = 1) then Sell tomorrow at liquidPoint stop;
if(MarketPosition =-1) then BuyTocover tomorrow at liquidPoint stop;

Trade Input Version 2

I have requests from some users to program a little more sophisticated version of my trade input strategy.  This is where you can simply list the trade, trade date, and trade price and TradeStation will plot the trades for you and calculate the performance.  This is a an easier to use program then TS’s _HistoricalEntry strategy.


{If you are entering the next bar then use the prior bars date
 Make sure your price is above or below open if stop or limit order
}

array: DateArray[1000](0),BorSArray[1000](""),PriceArray[1000](0);
vars: iCnt(1);

DateArray[1]=1141117;	BorSArray[1]="S";	PriceArray[1]=75.00;
DateArray[2]=1141219;	BorSArray[2]="F";	PriceArray[2]=59.01;
DateArray[3]=1150102;	BorSArray[3]="B";	PriceArray[3]=53.10;
DateArray[4]=1150210;	BorSArray[4]="S";	PriceArray[4]=50.00;


if date >= dateArray[1] then
begin
	if date = dateArray[iCnt] then
	begin
		if BorSArray[iCnt] = "B" then buy next bar at PriceArray[iCnt] stop;
		if BorSArray[iCnt] = "S" then sellShort next bar at PriceArray[iCnt] stop;
		if BorSArray[iCnt] = "F" then 
		begin
			if marketPosition = 1 then sell next bar at PriceArray[iCnt] stop;
			if marketPosition =-1 then buytocover next bar at PriceArray[iCnt] stop;
		end;
		iCnt = iCnt + 1;
	end;
end;

King Keltner from BWTSwTS Report

Like I stated in an earlier post the “Trend”, once a lost friend, is back. Check out the results from the King Keltner system as published in “Building Winning Trading Systems with TradeStation.” Looking at the results it looks like 2014 is as good as the “life saving” 2008. Is it time to re-think Trend Following – has the paradigm shifting pendulum swung back?

KingKeltner Report

HYPOTHETICAL PERFORMANCE RESULTS HAVE MANY INHERENT LIMITATIONS, SOME OF WHICH ARE DESCRIBED BELOW. NO REPRESENTATION IS BEING MADE THAT ANY ACCOUNT WILL OR IS LIKELY TO ACHIEVE PROFITS OR LOSSES SIMILAR TO THOSE SHOWN. IN FACT, THERE ARE FREQUENTLY SHARP DIFFERENCES BETWEEN HYPOTHETICAL PERFORMANCE RESULTS AND THE ACTUAL RESULTS SUBSEQUENTLY ACHIEVED BY ANY PARTICULAR TRADING PROGRAM.
ONE OF THE LIMITATIONS OF HYPOTHETICAL PERFORMANCE RESULTS IS THAT THEY ARE GENERALLY PREPARED WITH THE BENEFIT OF HINDSIGHT. IN ADDITION, HYPOTHETICAL TRADING DOES NOT INVOLVE FINANCIAL RISK, AND NO HYPOTHETICAL TRADING RECORD CAN COMPLETELY ACCOUNT FOR THE IMPACT OF FINANCIAL RISK IN ACTUAL TRADING. FOR EXAMPLE, THE ABILITY TO WITHSTAND LOSSES OR TO ADHERE TO A PARTICULAR TRADING PROGRAM IN SPITE OF TRADING LOSSES ARE MATERIAL POINTS WHICH CAN ALSO ADVERSELY AFFECT ACTUAL TRADING RESULTS. THERE ARE NUMEROUS OTHER FACTORS RELATED TO THE MARKETS IN GENERAL OR TO THE IMPLEMENTATION OF ANY SPECIFIC TRADING PROGRAM WHICH CANNOT BE FULLY ACCOUNTED FOR IN THE PREPARATION OF HYPOTHETICAL PERFORMANCE RESULTS AND ALL OF WHICH CAN ADVERSELY AFFECT ACTUAL TRADING RESULTS.