Using Virtual Trading Functions to Create Last Trade Loser Filter

The following code uses our new functions to synthetically keep track of our trading to determine when to enter a new trade. The Turtle System only took trades after a losing trade took place. Even with the Virtual Trade functions you still need to keep track of whether the entries/exits generated a profitable trade. It simple enough to track the real trades – compare the entries/exits when a the market position changes.

inputs: absEntryChanLen(55),entryChanlen(20),exitChanLen(10),lastTradeLoserFilter(false);

vars:lastTradeLoser(true),mp(0),virtmp(0),tradeProfit(0),virtBuyPrice(0),virtSellPrice(0),
myFillPrice(0);
mp = marketPosition;

If mp <> 1 and mp[1] = 1 then
Begin
	tradeProfit = ExitPrice(1) - EntryPrice(1);
	If tradeProfit > 0 then lastTradeLoser = false;
	print(date," Long Trader ",tradeProfit);
end;
If mp <> -1 and mp[1] = -1 then
Begin
	tradeProfit = EntryPrice(1) - ExitPrice(1);
	If tradeProfit > 0 then lastTradeLoser = false;
	print(date," Short Trader ",tradeProfit," ",lastTradeLoser);	
end;

If lastTradeLoserFilter = False then lastTradeLoser = True;

If lastTradeLoser = False then
Begin
	print(date," In Virtual Section And VirtTmp = ",virTmp);
	If(virtmp = 1) then
	Begin
		if(virtualLongExit(lowest(low[1],exitChanLen),1,myFillPrice) =1) then
		Begin
			tradeProfit = myFillPrice - virtBuyPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			virtmp = 0;
		end;
	end;	
	If(virtmp = -1) then
	Begin
		if(virtualShortExit(highest(high[1],exitChanLen),1,myFillPrice) =1) then
		Begin
			tradeProfit = virtSellPrice - myFillPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
			virtmp = 0;
		end;
	end;		
	if(virtualBuy(highest(high[1],entryChanLen),1,myFillPrice) = 1) then
	Begin
		if virtmp <> 1 then
		begin
			virtBuyPrice = myFillPrice;
			virtmp = 1;
			tradeProfit = 0;
			If virtmp[1] = -1 then tradeProfit = virtSellPrice - virtBuyPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
		end;
	end;
	if(virtualSell(lowest(low[1],entryChanLen),1,myFillPrice) = 1) then
	Begin
		if virtmp <> -1 then
		begin
			virtsellPrice = myFillPrice;
			virtmp = -1;
			tradeProfit = 0;
			If virtmp[1] = 1 then tradeProfit =  virtBuyPrice - virtSellPrice;
			If tradeProfit < 0 then lastTradeLoser = true;
		end;
	end;
	print("End of Virtual Module : virTmp = ",virTmp);
end; 

Replicate Turtle Trading by Creating Virtual Trade Functionality

My next little project is to create an EasyLanguage extender by creating a virtual trading function. The Turtle System always waits until a losing trade prior to taking a new trade. In EasyLanguage this doesn’t exist. This is similar to my Ghost Trader in Building Winning Trading Systems with TradeStation (1st and 2nd edition.)

In order to virtualize theoretical positions you must have the ability to enter/exit long/short positions. To carry this out we will create four functions:

virtualBuy
virtualSell
virtualLongExit
virtualShortExit

Information will need to be passed back and forth between the call program and the functions. Here is the template of the virtualBuy:

 Inputs: price(numericSimple),orderType(numericSimple),fillPrice(numericRef);
{Function to see if a virtual buy order was filled - we are passing the entry price, orderType
[stop,limit,market] and we will reply with with true or false and the fill price.
orderType: 
1 - Stop
2 - Limit
3 - Market}

VirtualBuy = 0;
Switch(orderType) 
Begin
Case 1:
	If high >= price then
	Begin
		fillPrice = maxList(open,price); {check for gap open}
		VirtualBuy = 1;
	end;
Case 2:
	If low < price then
	Begin
		fillPrice = minList(open,price); {check for gap open}
		VirtualBuy = 1;
	end;
Case 3:
	Begin
		fillPrice = open;
		VirtualBuy = 1;
	end;
Default:
	fillPrice = 999999;
	VirtualBuy = 0;
End;

Using CMI with Turtle Approach

Here is a nice little function that helps determine market choppiness. This function measures the actual distance the market moves against the total distance traveled. If the market starts in the lower left of your chart and moves, without much gyrations, to the upper right then the CMI will reflect a higher value. However if the market moves frantically around the chart and doesn’t achieve a great distance from the initial to the end points then the CMI will reflect a lower number.

Inputs: periodLength(NumericSimple);
Vars: num(0),denom(1);

if(periodLength<>0)then
begin
	denom = Highest(High,periodLength) - Lowest(Low,periodLength);
	num =Close[periodLength - 1]- Close;
		num = AbsValue(num);
	if (denom <> 0) then ChoppyMarketIndex = num/denom * 100;
end;

You can use the CMI function to help determine when you should follow a Turtle style break out. If the market has been trading in a range and you get a break out it might just carry a little more validity. Buying/Selling at really high/low prices may lead to false break outs.

Backtesting with [Trade Station,Python,AmiBroker, Excel]

Follow

Get every new post delivered to your Inbox

Join other followers: